Arduino and Visual Basic Part 1: Receiving Data From the Arduino

This is the first part of a guide about using a serial port to connect an Arduino to a Visual Basic app running on a PC. Communication is via the regular USB serial UART channel.

The first example is fairly simple, data is sent from the Arduino and displayed in a Visual Basic app.

This guide has been updated to Visual Studio / Visual Basic 2022, however, to keep things simple the app was created using Windows Forms App (.NET Framework).

Tools Required

Arduino + usb cable
PC with Visual Studio

• At the time of writing the latest version of Visual Studio is 2022. There are three editions;
• Community
• Professional
• Enterprise

Visual Studio Community is a full featured IDE and development system that is free for students, open-source contributors, and individuals. Caveat, you need a Microsoft account :-(

The download is an installer (not the full program), so download, run the installer, select which bits you want and install. Visual Studio supports many different languages and to follow this guide all you need is Windows Forms App (.NET Framework). It’s probably worthwhile installing all flavours of Visual Basic though.

There are two flavours of Visual Basic, Windows Form App (WFA) and WPF Application.

This guide uses Windows Forms App (.NET Framework) which is the older .NET framework (the new one being simply .NET). .NET Framework includes. NET up to version 4.8 and the newer .NET uses version 5+. The current version is version 8.

Windows Forms App (.NET Framework) has the serialPort as part of the designer and it can easily be added by dragging from the Toolbox. The newer .NET has removed serialPort from the designer and serial port creation is done through code only. Using the older framework makes life a little easier but be aware it is the older .NET framework

The main download page is at https://visualstudio.microsoft.com/downloads/

If you are new to the IDE then it would be worth while watching a few guides., Microsoft have some good ones to start with:
Getting started with Visual Studio IDE
Tour the Visual Studio IDE

Arduino to Visual Basic Communication

Rather than building the app step by step (although I kind of do that with the various parts of this guide), it’s easier to have a working version straight away and explain what the parts do. I start with the Arduino Sketch.

The Arduino Sketch

The Arduino Sketch is fairly simple, it sends ASCII data (a count) over the serial connection once every second. At the same time it sends data it blinks the built in LED on pin 13.

It’s worth noting that the Arduino doesn’t care if anything is listening. It blindly sends the data until you turn it off.

/* 
* Sketch Arduino and Visual Basic Part 1 - Receiving Data From the Arduino
* Send a count over a serial connection once a second
* https://www.martyncurrey.com/arduino-and-visual-basic-part-1-receiving-data-from-the-arduino/
*/

byte LEDpin = 13;
int count = 1000;

void setup() 
{
     pinMode(LEDpin, OUTPUT); 
     Serial.begin(9600);
}

void loop() 
{
     Serial.println(count);
     count = count + 1;      //  count++;  also works, it's the same

     // flash the onboard LED to show data is being sent
     digitalWrite(LEDpin,HIGH);      delay(100);
     digitalWrite(LEDpin,LOW);       delay(900);
}     

To check that the sketch works, upload the code and open the serial monitor. You can also take a note of the COM port. Mine is COM12 yours will likely be different.

I use version 1 IDE. I use potable IDEs and the new V2 IDE doesn’t support full portable installation yet.

All we are going to do is replace the serial monitor with a Visual Basic app.

Open The Visual Basic App In Visual Studio

Assuming you have Visual Studio installed, download Arduino-Visual-Basic-Part-1 VB project. The download is a zip file, inside the zip file is a folder. Inside the folder are the project files.

The easiest way to open the project is to double click the .sln file.

Visual Basic apps, generally, have two parts, the form and the code. The form is created using the designer. The code is created using the text editor.

A note for the pedantic. The form can also be created in code should you desire.

Double click the Arduino_Visual-Basic.sln.sln file. This should start Visual Studio and load the project.

If Visual Studio opens with an empty work space, right click Form1.vb (top right) and select View Designer, or, press Shift + F7 (or simply double click Form1.vb).

The Main Form

This example uses a very simply form that only has 5 active elements

• COM PORT drop down list
• CONNECT button
• RECEIVED DATA text box
• CLEAR button
• TIMER label

COM PORT drop down list
This is a comboBox, dropDownStyle is drop down list.
When the app first starts, the COM PORT list is populated with all the available COM ports.

CONNECT button
This is a regular button
After selecting a COM PORT, when the CONNECT button is clicked the app tries to open a serial port using the COM port selected in the drop down list.

RECEIVED DATA text box
This is a RichTextBox
The data received via the serial channel is copied to the text box.

CLEAR button
Regular button, used to clear the text box.

TIMER label
A label used to show the status of the timer, The timer is used to trigger a check to see if any new data has been received. Normally you would not need to show the status. What ever the app receives from the Arduino (ASCII) it adds to the text box.

Added via the designer, there is also a SerialPort and Timer.

To see the code, right click Form1.vb again and select View Code, or, press F7 (or simply double click anywhere inside the Form1 form).

Try The Visual Basic App

Let’s see if the app works. Connect the Arduino to the PC and confirm what COM port the Arduino has connected to. Mine is COM14, yours is likely not.

In Visual Studio click the Start button at the top of the screen

The code will compile and the app will run. You should see the main form. All good so far.

Select the COM port the Arduino is connected to and hit CONNECT.

If there are no issues, the app will connect to the Arduino and the count will start to appear in the text box.
The CONNECT button changes to DIS-CONNECT, and , you will never guess but, if you click the DIS-CONNECT button the serial channel is closed.

The Visual Basic Program

Here is the code

' Arduino and Visual Basic Part 1: Receiving Data From An Arduino
' A simple example of recieving serial data from an Arduino and displaying it in a text box
' https://www.martyncurrey.com/arduino-and-visual-basic-part-1-receiving-data-from-the-arduino/
'

Imports System
Imports System.IO.Ports
Imports System.Windows.Forms.VisualStyles.VisualStyleElement


Public Class Form1

    ' Global variables.
    ' Anything defined here is available in the whole app
    Dim selected_COM_PORT As String
    Dim receivedData As String = ""

    ' This called when the app first starts. Used to initial what ever needs initialising.
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Timer1.Enabled = False
        selected_COM_PORT = ""
        For Each sp As String In My.Computer.Ports.SerialPortNames
            comPort_ComboBox.Items.Add(sp)
        Next
    End Sub

    ' When the value of the COM PORT drop doewn list changes,
    ' copy the new value to the comPORT variable.
    Private Sub comPort_ComboBox_SelectedIndexChanged(sender As Object, e As EventArgs) Handles comPort_ComboBox.SelectedIndexChanged
        If (comPort_ComboBox.SelectedItem <> "") Then
            selected_COM_PORT = comPort_ComboBox.SelectedItem
        End If
    End Sub

    ' Try to open the com port or close the port if already open
    ' Note: There is no error catching. If the connection attampt fails the app will crash!
    Private Sub connect_BTN_Click(sender As Object, e As EventArgs) Handles connect_BTN.Click
        If (connect_BTN.Text = "CONNECT") Then
            If (selected_COM_PORT <> "") Then

                ' Try allows me to trap an errors such as the COM port not being available
                ' Without it the app crashes.
                Try
                    SerialPort1.PortName = selected_COM_PORT
                    SerialPort1.BaudRate = 9600
                    SerialPort1.DataBits = 8
                    SerialPort1.Parity = Parity.None
                    SerialPort1.StopBits = StopBits.One
                    SerialPort1.DtrEnable = True
                    SerialPort1.RtsEnable = True
                    SerialPort1.Handshake = Handshake.None
                    SerialPort1.Encoding = System.Text.Encoding.Default 'very important!
                    SerialPort1.ReadTimeout = 10000

                    SerialPort1.Open()

                Catch ex As Exception
                    MessageBox.Show(ex.Message + vbCrLf + "Looks like something else is using it.", "Error openning the serial port", MessageBoxButtons.OK, MessageBoxIcon.Error)
                End Try

            Else
                MsgBox("No COM port selected!")
            End If
        Else
            Try
                SerialPort1.Close()
            Catch ex As Exception
                MessageBox.Show("Serial Port is already closed!")
            End Try
        End If

        ' A bit wastful of space but seperating openning the post and setting the variables like this makes the
        ' code a liitle more clear.
        If (SerialPort1.IsOpen) = True Then
            connect_BTN.Text = "DIS-CONNECT"
            Timer1.Enabled = True
            timer_LBL.Text = "TIMER: ON"
        Else
            connect_BTN.Text = "CONNECT"
            Timer1.Enabled = False
            timer_LBL.Text = "TIMER: OFF"
        End If

    End Sub

    ' Process received data. Append the data to the text box
    Private Sub Timer1_Tick(sender As Object, e As EventArgs) Handles Timer1.Tick
        receivedData = ReceiveSerialData()
        recData_RichTextBox.AppendText(receivedData)
    End Sub

    ' Check for new data
    Function ReceiveSerialData() As String
        Dim Incoming As String
        Try
            Incoming = SerialPort1.ReadExisting()
            If Incoming IsNot Nothing Then
                Return Incoming
            End If
        Catch ex As TimeoutException
            Return "Error: Serial Port read timed out."
        End Try

    End Function

    ' Clear the text box
    Private Sub clear_BTN_Click(sender As Object, e As EventArgs) Handles clear_BTN.Click
        recData_RichTextBox.Text = ""
    End Sub

End Class

The program in Detail

I am using two global variables; selected_COM_PORT and receivedData.
selected_COM_PORT is the COM port selected by the user in the drop down list.
receivedData is the data received via the COM port / serial channel.

   ' Global variables.
   ' Anything defined here is available in the whole app
   Dim selected_COM_PORT As String
   Dim receivedData As String = ""

 
When the program is first run, the Form1_Load() subroutine is run automatically and is an ideal place to perform any required initialization, such as, populating the COM port combo box / drop down list with the available COM ports.
Not really required but the timer is made inactive. This is a comfort blanket statement.

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Timer1.Enabled = False
        selected_COM_PORT = ""
        For Each sp As String In My.Computer.Ports.SerialPortNames
            comPort_ComboBox.Items.Add(sp)
        Next
    End Sub

After this, the program sits and waits for the user to do something.

When the user finally gets round to selecting a COM port in the drop down list, the selected value is copied to the variable selected_COM_PORT . This is not really necessary as the selected value can be read directly from the combo box at any time but I like to keep this kind of data in easy to use variables.

Private Sub comPort_ComboBox_SelectedIndexChanged(sender As Object, e As EventArgs) Handles comPort_ComboBox.SelectedIndexChanged
        If (comPort_ComboBox.SelectedItem <> "") Then
            selected_COM_PORT = comPort_ComboBox.SelectedItem
        End If
    End Sub

 
When the CONNECT button is clicked the Sub connect_BTN_Click() function is called.
The first thing the routine does is determine if the user is connecting or dis-connecting. The same button is used for both.

If connecting and selected_COM_PORT is not empty the serial port properties are set, the serial port is opened and the timer is started. If selected_COM_PORT is empty a message is displayed sating no COM port is selected.

If dis-connecting, the serial port is closed..

Private Sub connect_BTN_Click(sender As Object, e As EventArgs) Handles connect_BTN.Click
    If (connect_BTN.Text = "CONNECT") Then
        If (selected_COM_PORT <> "") Then

            ' Try allows me to trap an errors such as the COM port not being available
            ' Without it the app crashes.
            Try
                SerialPort1.PortName = selected_COM_PORT
                SerialPort1.BaudRate = 9600
                SerialPort1.DataBits = 8
                SerialPort1.Parity = Parity.None
                SerialPort1.StopBits = StopBits.One
                SerialPort1.DtrEnable = True
                SerialPort1.RtsEnable = True
                SerialPort1.Handshake = Handshake.None
                SerialPort1.Encoding = System.Text.Encoding.Default 'very important!
                SerialPort1.ReadTimeout = 10000

                SerialPort1.Open()

            Catch ex As Exception
                MessageBox.Show(ex.Message + vbCrLf + "Looks like something else is using it.", "Error opening the serial port", MessageBoxButtons.OK, MessageBoxIcon.Error)
            End Try

        Else
            MsgBox("No COM port selected!")
        End If
    Else
        Try
            SerialPort1.Close()
        Catch ex As Exception
            MessageBox.Show("Serial Port is already closed!")
        End Try
    End If

The Try / Catch ex As Exception statements are there to catch an errors, for example, if you try to open a COM port that something else is using VB throws a tantrum.

Instead of crashing the app, the Try / Catch ex As Exception let’s use deal with the problem. In this case by displaying an error message.

After the serial port is either opened or closed the elements associated with the serial port are updated.
If the serial port is open, the timer is started and the CONNECT button text is changed to DIS-CONNECT.
If the serial port is closed, the timer is stopped and the button text is set to CONNECT.

        If (SerialPort1.IsOpen) = True Then
            connect_BTN.Text = "DIS-CONNECT"
            Timer1.Enabled = True
            timer_LBL.Text = "TIMER: ON"
        Else
            connect_BTN.Text = "CONNECT"
            Timer1.Enabled = False
            timer_LBL.Text = "TIMER: OFF"
        End If

The timer_LBL is there purely for debugging.

 
The timer is used to check for incoming data. The timer is set to trigger every 100ms, or tenth of a second, and when triggered it calls the Timer1_Tick() routine. For this example 500ms is fast enough. For more complex tasks the timing may need to be adjusted.

If data has been received it is appended to the text box.

    Private Sub Timer1_Tick(sender As Object, e As EventArgs) Handles Timer1.Tick
        receivedData = ReceiveSerialData()
        If (receivedData <> "") Then
            recData_RichTextBox.AppendText(receivedData)
        End If

 
Timer1_Tick() calls a second subroutine that does the actual checking. If there is any serial data the data is returned to the calling function.

    Function ReceiveSerialData() As String
        Dim Incoming As String = ""
        Try
            Incoming = SerialPort1.ReadExisting()
            If Incoming IsNot Nothing Then
                Return Incoming
            End If
        Catch ex As TimeoutException
            Return "Error: Serial Port read timed out."
        End Try
    End Function

 
The final bit is the function that deals with the CLEAR button. Here the text box contents are simple reset to nul.

    Private Sub clear_BTN_Click(sender As Object, e As EventArgs) Handles clear_BTN.Click
        recData_RichTextBox.Text = ""
    End Sub

Serial Port

The main part of the code is opening the serial port.

Because the example uses Net Framework with .NET4.8, the serial port object can be added to the app in the designer. This means the serial port properties are available in the designer.

Although I included the4 serialPort in the designer, I am setting the properties in code. I prefer this way so that in the future, should I want to allow the user to edit the values it can be done a little quicker. In the example though, only the COM port is being selected by the user.

                SerialPort1.PortName = selected_COM_PORT
                SerialPort1.BaudRate = 9600
                SerialPort1.DataBits = 8
                SerialPort1.Parity = Parity.None
                SerialPort1.StopBits = StopBits.One
                SerialPort1.DtrEnable = True
                SerialPort1.RtsEnable = True
                SerialPort1.Handshake = Handshake.None
                SerialPort1.Encoding = System.Text.Encoding.Default 'very important!
                SerialPort1.ReadTimeout = 10000

                SerialPort1.Open()

Baud Rate
The baud rate is set to 9600 for bothe the Visual Basic app and the Arduino sketch.

Data, Partity, And Stop Bits
SerialPort1.DataBits = 8
SerialPort1.Parity = Parity.None
SerialPort1.StopBits = StopBits.One
These define the serial port configuration settings this set of values is often refered to 8N1
– 8 data bits
– No parity
– 1 stop bit.8N1 is a fairly common setting and used as the default for many devices.

DTR
SerialPort1.DtrEnable = True
DTR (Data Terminal Ready) is a control signal sent to the connected device (in this case the Arduino) to let it know the Visual Basic app is ready to communicate.

RTS
SerialPort1.RtsEnable = True
RTS (Request To Send) is another control signal used to let the connected device know the app has data to send. RTS has a companion setting called CTS which is not used in the Visual Basic app.

Arduino serial (hardware and software) does not use RTS and DTS for flow control. DTR is used as a reset signal though. DTR is connected to Arduino reset so when a DTR signal is received the Arduino will automatically reset itself.

Handshake
SerialPort1.Handshake = Handshake.None
The Arduino doesn’t perform any handshaking when establishing a serial connection so we set Handshake to none.

Trouble Shooting

This is a very simple example that shows the basics about making a serial connection between the Arduino and a computer. As such the code can be improved

• The COM port is left open all the time and for more complex applications it may be better to open and close the port as required.
• The application simply displays what data is received. The data is not checked and could be anything, even non-prinatble characters.

Download

Download the Arduino sketch
Download the Visual Basic project You will need to have Visual Studio installed to use the VB project files.  

Next Steps

In part 2 we take this further and in part 3 we start to control an Arduino

More On Using Serial Data

If you want to know more about using serial data with the Arduino, have a look at the Arduino Serial Guides.